IMEXP Function in Excel

Excel’s IMEXP function calculates e (the constant 2.71828…) raised to the power of a complex number. You give it something like 1+i, and it gives you back another complex number.

You’ll mostly need it in math and engineering work. That’s because e raised to an imaginary power is how you turn an angle into a point on a circle, which comes up when you rotate shapes or work with AC circuits.

There are two catches. The result always comes back as text with up to 15 digits, and IMEXP won’t take a range of cells directly, so a whole-column formula needs a small trick.

In this article, I’ll show you how to use the IMEXP function with four practical examples, including how to clean up the long decimals it often returns.

IMEXP Function Syntax

Here is the syntax of the IMEXP function:

=IMEXP(inumber)

• inumber – The complex number you want to raise e to. It can be text like “3+4i” or “3+4j”, a cell that holds one, or a plain number.

When you type a complex number straight into the formula, put it in double quotes. For example, =IMEXP("1+i") returns 1.46869393991589+2.28735528717884i.

A plain number works too, and IMEXP treats it as a complex number with no imaginary part. But the answer still comes back as text, so =IMEXP(2) gives you 7.38905609893065 as text.

For regular numbers, the EXP function is the better choice, because it returns the same value as a real number you can format and add up.

The i or j has to be lowercase, and the result uses the same letter as your input. A value like “3+4I” isn’t recognized as a complex number, so IMEXP returns the #NUM! error.

The IMEXP function works in Excel for Microsoft 365, Excel 2024, 2021, 2019, 2016, and Excel for Mac.

When to Use the IMEXP Function

Use this function when you need to:

• Calculate e raised to a complex number in a math or engineering worksheet
• Turn an angle into a point on the unit circle (Euler’s formula)
• Rotate points on a grid by any angle
• Work with AC circuit or signal values written in j notation

Let me show you a few practical examples of how to use the IMEXP function.

Example 1: Calculate e Raised to a Complex Number

Let’s start with a simple example.

Below is a practice set of complex numbers, and I want to calculate e raised to each one in column C.

Here is the formula to enter in cell C2 and copy down:

=IMEXP(B2)

IMEXP takes the complex number in B2 and raises e to that power. For a number a+bi, Excel works it out as e to the power a, multiplied by (cos b + i sin b), with b read as an angle in radians.

For 2+3i in problem 2, e squared is about 7.39, cos 3 is about -0.99, and sin 3 is about 0.14. Multiply those out and you get -7.3151100949011+1.0427436562359i.

Problems 6 and 8 are plain numbers (3 and -2), so IMEXP gives the same values as the EXP function, 20.0855369231877 and 0.135335283236613. They’re still text, though.

I’ve kept this first example as a per-row formula so you can see how IMEXP handles one number at a time. The next example does the whole column with one formula.

Example 2: Use IMEXP on a Whole Column with One Formula

In Excel 365 (and Excel 2021 or later), you can calculate a whole column with a single formula, but IMEXP needs one small trick to do it.

Below is a list of complex numbers from an AC circuits worksheet written in j notation, and I want to get e raised to each one in column C.

The obvious formula would be to give IMEXP the whole range. I’ve put that attempt in cell F2, and it returns a #VALUE! error:

=IMEXP(B2:B11)

This happens because IMEXP can’t take a multi-cell range reference like B2:B11. It only works with single values, or with a list of values held in memory (called an array).

Putting a plus sign (+) in front of the range fixes this, because Excel then hands IMEXP the values as an array. Here is the formula that works:

=IMEXP(+B2:B11)

Enter this in cell C2, and it spills the results down to C11. Since the inputs use j, the results use j too, and the plain number 1.5 in exercise 10 gives 4.48168907033806.

Important: Use just the plus sign here. A double minus (–) or +0 also creates an array, but it tries to turn the text into numbers first, so every complex number returns #VALUE!.

The same plus-sign trick works for other functions that won’t spill when you give them a range.

If you are using Excel 2019 or earlier, enter the below formula in cell C2 and then copy it down the range:

=IMEXP(B2)

Example 3: Use Euler’s Formula to Get Points on a Circle

Now let’s look at a classic use of IMEXP. It helps to picture a complex number x+yi as a point on a grid, x across and y up from zero, so 1 is one step to the right and i is one step straight up.

When a complex number has no real part, like 0+θi (where θ is an angle in radians), e raised to it always lands on a circle with a radius of 1 around zero. This is called the unit circle.

That’s Euler’s formula: e raised to iθ equals cos θ + i sin θ. The angle is measured counterclockwise from the right, so 90 degrees lands straight up at i, and 180 degrees lands at -1.

Below is a list of angles in degrees, and I want to get the point on the unit circle for each angle in column B.

Here is the formula to enter in cell B2:

=IMEXP(COMPLEX(0,RADIANS(A2:A11)))

How this formula works:

• RADIANS(A2:A11) converts the angles from degrees to radians, because IMEXP reads the imaginary part as an angle in radians.
• COMPLEX(0, …) builds a complex number with 0 as the real part and the angle as the imaginary part. For 90 degrees, that’s 1.5707963267949i (Excel leaves out a real part of 0).
• IMEXP(…) raises e to each of those numbers, which gives the point on the unit circle.

This one spills down to B11 without a plus sign. The RADIANS function already returns an array, so IMEXP never sees a range reference.

The results are right, but some of them look odd. The 90-degree point should be just i, but it shows as -3.49145625605507E-15+i, and 180 degrees shows -1+3.2311393144413E-15i instead of -1.

Those E-15 values are tiny leftovers (0.0000000000000035) from how computers store decimals.

With a regular number, you could use number formatting to show fewer decimals. But IMEXP’s result is text, so number formatting can’t touch it.

You can’t fix this with the ROUND function directly, because the result is text and ROUND returns a #VALUE! error. Instead, round the real and imaginary parts separately and join them back.

Here is the formula to enter in cell C2:

=LET(z,IMEXP(COMPLEX(0,RADIANS(A2:A11))),COMPLEX(ROUND(IMREAL(z),4),ROUND(IMAGINARY(z),4)))

How this formula works:

• IMEXP(COMPLEX(0,RADIANS(A2:A11))) gets the points, and the LET function stores them as z, so the calculation runs only once.
• IMREAL(z) and IMAGINARY(z) pull out the real and imaginary parts as regular numbers.
• ROUND(…,4) rounds each part to four decimal places.
• COMPLEX(…) joins the two rounded parts back into a complex number.

Now 90 degrees shows i, 180 degrees shows -1, and 30 degrees shows 0.866+0.5i, which are the cosine and sine of 30 degrees.

Both formulas spill, and the LET function needs Excel 2021 or later. If you are using Excel 2019 or earlier, enter the below formula in cell B2 and then copy it down the range:

=IMEXP(COMPLEX(0,RADIANS(A2)))

And for the rounded points, enter the below formula in cell C2 and then copy it down the range:

=COMPLEX(ROUND(IMREAL(IMEXP(COMPLEX(0,RADIANS(A2)))),4),ROUND(IMAGINARY(IMEXP(COMPLEX(0,RADIANS(A2)))),4))

Example 4: Rotate Points with IMEXP

Let’s step it up with something more practical. If you write a point on a grid as a complex number (x+yi), multiplying it by e raised to iθ rotates that point counterclockwise around zero by the angle θ.

Below are the corner points of an arrow shape drawn on a grid, and I want to rotate the arrow by the angle in cell F2 and get the new points in column C.

Each point is written as x+yi, so 3+2i is the point 3 across and 2 up.

Here is the formula to enter in cell C2 and copy down:

=LET(p,IMPRODUCT(B2,IMEXP(COMPLEX(0,RADIANS($F$2)))),COMPLEX(ROUND(IMREAL(p),2),ROUND(IMAGINARY(p),2)))

How this formula works:

• IMEXP(COMPLEX(0,RADIANS($F$2))) turns the 90 degrees in F2 into a rotation factor, the point on the unit circle at that angle. For 90 degrees, that’s i (plus the tiny leftover you saw in Example 3).
• IMPRODUCT(B2, …) multiplies the point in B2 by the rotation factor, which rotates it by 90 degrees.
• LET stores the rotated point as p, and the ROUND part works just like in Example 3 (this time to two decimals). So point B (3+i in B3) shows -1+3i instead of -1.00000000000001+3i.

The arrow pointed to the right before, and now it points up. Point D, the tip at 5, moved to 5i, and point B moved from 3+i to -1+3i.

Since the angle sits in its own cell, you can change F2 to 45 or 180, and every point updates. The $ signs keep the formula pointing at F2 when you copy it down.

I’ve kept this as a per-row formula because the IMPRODUCT function multiplies everything you give it into a single result. Feeding it the whole column would multiply all seven points together instead of rotating each one.

So these are some practical ways to use the IMEXP function in Excel to calculate e raised to a complex number, get points on a circle, and rotate shapes.

Just remember to put a plus sign in front of a plain range when you want one formula for a whole column. I hope you found this article helpful.

List of All Excel Functions

Other Excel Articles You May Also Like:

• IMSUB Function in Excel
• Cosine Function (COS) in Excel
• IMLN guide
• IMPOWER Function in Excel
• IMSQRT
• IMTAN function